Add support for `solc` Solidity compiler (#2648)

* Add support for `solc` Solidity compiler
* Set default value for `solidity_solc_options`
* Add test for solc handler

ale_linters/solidity/solc.vim

@@ -0,0 +1,35 @@
+" Author: Karl Bartel <karl42@gmail.com> - http://karl.berlin/
+" Description: Report solc compiler errors in Solidity code
+
+call ale#Set('solidity_solc_options', '')
+
+function! ale_linters#solidity#solc#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    " /path/to/file/file.sol:1:10: Error: Identifier not found or not unique.
+    let l:pattern = '\v^[^:]+:(\d+):(\d+): (Error|Warning): (.*)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:isError = l:match[3] is? 'error'
+        call add(l:output, {
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 0,
+        \   'text': l:match[4],
+        \   'type': l:isError ? 'E' : 'W',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#solidity#solc#GetCommand(buffer) abort
+    return 'solc' . ale#Pad(ale#Var(a:buffer, 'solidity_solc_options')) . ' %s'
+endfunction
+
+call ale#linter#Define('solidity', {
+\   'name': 'solc',
+\   'executable': 'solc',
+\   'command': function('ale_linters#solidity#solc#GetCommand'),
+\   'callback': 'ale_linters#solidity#solc#Handle',
+\   'output_stream': 'stderr',
+\})

test/handler/test_solc_handler.vader

@@ -0,0 +1,30 @@
+Before:
+  runtime ale_linters/solidity/solc.vim
+
+After:
+  call ale#linter#Reset()
+
+Execute(Check solc output parsing):
+  AssertEqual
+  \ [
+  \   {
+  \     'lnum': 40,
+  \     'col': 48,
+  \     'text': 'This declaration shadows an existing declaration.',
+  \     'type': 'W',
+  \   },
+  \   {
+  \     'lnum': 23,
+  \     'col': 16,
+  \     'text': 'Member "getSinleSignature" not found or not visible after argument-dependent lookup in type(contract OneToN).',
+  \     'type': 'E',
+  \   },
+  \ ],
+  \ ale_linters#solidity#solc#Handle(bufnr(''), [
+  \   'raiden_contracts/data/source/raiden/Token.sol:40:48: Warning: This declaration shadows an existing declaration.',
+  \   '   function decimals() external view returns (uint8 decimals);',
+  \   '                                              ^------------^',
+  \   '/home/karl/raiden-contracts/raiden_contracts/data/source/test/OneToNInternalsTest.sol:23:16: Error: Member "getSinleSignature" not found or not visible after argument-dependent lookup in type(contract OneToN).',
+  \   '       return OneToN.getSinleSignature(signatures, i);',
+  \   '              ^----------------------^',
+  \ ])