Merge pull request #1618 from colbydehart/master

[new linter] Add mix linter for elixir

README.md

@@ -113,7 +113,7 @@ formatting.
 | Dafny | [dafny](https://rise4fun.com/Dafny) !! |
 | Dart | [dartanalyzer](https://github.com/dart-lang/sdk/tree/master/pkg/analyzer_cli) !!, [language_server](https://github.com/natebosch/dart_language_server) |
 | Dockerfile | [hadolint](https://github.com/hadolint/hadolint) |
-| Elixir | [credo](https://github.com/rrrene/credo), [dialyxir](https://github.com/jeremyjh/dialyxir), [dogma](https://github.com/lpil/dogma) !!|
+| Elixir | [credo](https://github.com/rrrene/credo), [dialyxir](https://github.com/jeremyjh/dialyxir), [dogma](https://github.com/lpil/dogma), [mix](https://hexdocs.pm/mix/Mix.html) !!|
 | Elm | [elm-format](https://github.com/avh4/elm-format), [elm-make](https://github.com/elm-lang/elm-make) |
 | Erb | [erb](https://apidock.com/ruby/ERB), [erubi](https://github.com/jeremyevans/erubi), [erubis](https://github.com/kwatch/erubis) |
 | Erlang | [erlc](http://erlang.org/doc/man/erlc.html), [SyntaxErl](https://github.com/ten0s/syntaxerl) |

ale_linters/elixir/mix.vim

@@ -0,0 +1,61 @@
+" Author: evnu - https://github.com/evnu
+" Author: colbydehart - https://github.com/colbydehart
+" Description: Mix compile checking for Elixir files
+
+function! ale_linters#elixir#mix#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    "
+    " Error format
+    " ** (CompileError) apps/sim/lib/sim/server.ex:87: undefined function update_in/4
+    "
+    " TODO: Warning format
+    " warning: variable "foobar" does not exist and is being expanded to "foobar()", please use parentheses to remove the ambiguity or change the variable name
+
+    let l:pattern = '\v\(([^\)]+Error)\) ([^:]+):([^:]+): (.+)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:type = 'E'
+        let l:text = l:match[4]
+
+        call add(l:output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[3] + 0,
+        \   'col': 0,
+        \   'type': l:type,
+        \   'text': l:text,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#elixir#mix#FindProjectRoot(buffer) abort
+    let l:mix_file = ale#path#FindNearestFile(a:buffer, 'mix.exs')
+    if !empty(l:mix_file)
+      return fnamemodify(l:mix_file, ':p:h')
+    endif
+    return '.'
+endfunction
+
+function! ale_linters#elixir#mix#GetCommand(buffer) abort
+    let l:project_root = ale_linters#elixir#mix#FindProjectRoot(a:buffer)
+
+    let l:temp_dir = ale#engine#CreateDirectory(a:buffer)
+
+    let l:mix_build_path = has('win32')
+    \   ? 'set MIX_BUILD_PATH=' . ale#Escape(l:temp_dir) . ' &&'
+    \   : 'MIX_BUILD_PATH=' . ale#Escape(l:temp_dir)
+
+    return ale#path#CdString(l:project_root)
+          \ . l:mix_build_path
+          \ . ' mix compile %s'
+endfunction
+
+call ale#linter#Define('elixir', {
+\   'name': 'mix',
+\   'executable': 'mix',
+\   'command_callback': 'ale_linters#elixir#mix#GetCommand',
+\   'callback': 'ale_linters#elixir#mix#Handle',
+\   'lint_file': 1,
+\})

doc/ale.txt

@@ -338,7 +338,7 @@ Notes:
 * Dafny: `dafny`!!
 * Dart: `dartanalyzer`!!, `language_server`
 * Dockerfile: `hadolint`
-* Elixir: `credo`, `dialyxir`, `dogma`!!
+* Elixir: `credo`, `dialyxir`, `dogma`, `mix`!!
 * Elm: `elm-format, elm-make`
 * Erb: `erb`, `erubi`, `erubis`
 * Erlang: `erlc`, `SyntaxErl`

test/command_callback/mix_paths/wrapped_project/mix.exs

@@ -0,0 +1 @@
+use Mix.Config

test/command_callback/test_elixir_mix_command_callbacks.vader

@@ -0,0 +1,37 @@
+Before:
+  runtime ale_linters/elixir/mix.vim
+
+  call ale#test#SetDirectory('/testplugin/test/command_callback')
+
+  let g:project_root = ale#path#Simplify(g:dir . '/mix_paths/wrapped_project')
+
+  let g:env_prefix = has('win32')
+  \ ? 'set MIX_BUILD_PATH=TEMP && '
+  \ : 'MIX_BUILD_PATH=TEMP '
+
+
+  function! GetCommand(buffer) abort
+    let l:command = ale_linters#elixir#mix#GetCommand(a:buffer)
+
+    return substitute(l:command, 'MIX_BUILD_PATH=[^ ]\+', 'MIX_BUILD_PATH=TEMP', '')
+  endfunction
+
+After:
+  Restore
+
+  unlet! g:env_prefix
+  unlet! g:project_root
+
+  call ale#linter#Reset()
+  call ale#test#RestoreDirectory()
+
+  delfunction GetCommand
+
+Execute(The default mix command should be correct):
+  call ale#test#SetFilename('mix_paths/wrapped_project/lib/app.ex')
+
+  AssertEqual
+  \ GetCommand(bufnr('')),
+  \ ale#path#CdString(g:project_root)
+  \ . g:env_prefix
+  \ . 'mix compile %s'

test/handler/test_mix_handler.vader

@@ -0,0 +1,21 @@
+Before:
+  runtime ale_linters/elixir/mix.vim
+
+After:
+  call ale#linter#Reset()
+
+Execute(The mix handler should parse lines correctly):
+
+  AssertEqual
+  \ [
+  \   {
+  \     'bufnr': 347,
+  \     'lnum': 87,
+  \     'col': 0,
+  \     'text': 'undefined function update_in/4',
+  \     'type': 'E',
+  \   },
+  \ ],
+  \ ale_linters#elixir#mix#Handle(347, [
+  \   '** (CompileError) apps/sim/lib/sim/server.ex:87: undefined function update_in/4'
+  \ ])